五条够用的写法

打开 CMD 后要落到某个文件夹里,记住五条就够:

cd /d "D:\work\my project"      :: 跨盘符 + 带空格,一条搞定
pushd "D:\logs\2026-11"         :: 去别处看一眼
popd                            :: 回到原处
start .                         :: 用资源管理器打开当前目录
pushd \\server\share            :: 网络路径只能走 pushd
  • cd /d 管跨盘:不写 /d,切盘符那一步不会生效。
  • 引号管特殊字符:空格可省,&、^、(、)、% 必须加。
  • pushd/popd 管来回,也是唯一能进网络路径的办法。

一、cd D:\work 为什么没反应

C:\Users\你>cd D:\work
C:\Users\你>_

命令没报错,提示符也没动。

原因:CMD 给每个盘符各记一个「当前目录」。cd D:\work 改的是 D 盘那边的当前目录,而人还站在 C 盘,提示符自然不变。

解决:

cd /d D:\work

/d 是 drive 的意思,允许盘符和目录一起切。等价于分两步写的 cd D:\work + D:。

截图

同类易错写法

写法 实际结果
cd D:\work 只改 D 盘的当前目录,人不移动
cd C: 只打印 C 盘当前目录,不切换
cd /d C: 这才真的切过去
cd notepad.exe 报「目录名无效」,cd 只能进目录
在根目录再敲 cd .. 不报错,原地不动

相对路径速查

命令 效果
cd 子目录 进入当前目录下的子目录
cd .. 回上一级
cd ..\.. 连退两级
cd \ 回当前盘的根目录
cd 打印当前路径
echo %CD% 打印当前路径(bat 脚本里更稳)

想确认自己在哪,提示符本身就在显示完整路径。只有路径被截断、写在脚本里、或提示符被改过时,才需要 cd 或 echo %CD%。


二、路径里有空格,到底要不要加引号

路径里含 要不要引号 写法
空格 不需要 cd D:\work\cmd nav test
& ( ) ^ % 必须加 cd "D:\work\cmd&nav"
不确定 一律加 最省心

空格为什么不炸:cd 把命令后面整段当成一个路径,空格只是路径的一部分。

& 为什么炸:& 是命令分隔符,CMD 会先把这一行切成两段再执行。

cd D:\work\cmd&nav
系统找不到指定的路径。
'nav' 不是内部或外部命令,也不是可运行的程序
或批处理文件。

前一句是 cd ...\cmd 找不到目录,后一句是把 nav 当命令跑了。加引号即正常:

cd "D:\work\cmd&nav"

截图

规则压成一条:start、copy 这类按空格拆参数的命令,路径一律加引号。cd 虽然能省,但统一加比记「什么时候能省」便宜。


三、pushd 和 popd 怎么用

C:\Windows>pushd D:\
D:\>popd
C:\Windows>_

pushd 把当前位置压栈再跳走,popd 弹栈回来——连盘符一起还原,不用先敲 C:。

它能进网络路径,cd 不能

pushd \\localhost\C$\Windows

会自动挂一个盘符(本机是 Z:)并进入,popd 回原目录时映射自动断开。同样这条路径交给 cd /d:

CMD 不支持将 UNC 路径作为当前目录。

截图

两个要知道的点

  • 栈空时执行 popd:无输出、退出码 0、不报错。别拿它判断「有没有可回退的位置」。
  • 目标盘符被占用时会顺延到下一个可用盘符,脚本里不要写死 Z:\。

bat 里的标准姿势

@echo off
pushd "%~dp0"
cd work
echo 正在处理 %CD%
popd

%~dp0 是「脚本自身所在目录,带末尾反斜杠」,所以后面直接接子目录名,不用再补 \。开头压栈、结尾弹栈,跑完不会把调用者的当前目录改掉。


四、start . 和 explorer . 的区别

命令 效果 退出码 用哪个
start . 新开资源管理器窗口,地址是当前目录,CMD 位置不变 可靠 默认选它
explorer . 打开的窗口一样 不稳定(同一条命令两次分别返回 0 和 1) 脚本里别用

start 后面的 . 就是当前目录。想打开上级写 start ..,想直接打开文件写 start readme.txt。

截图


一段能直接用的脚本

路径换成你自己的:

cd /d "D:\work\my project"

pushd "D:\logs\2026-11"
dir *.log
popd

start .

常见报错对照

报错或现象 原因 处理
敲完 cd D:\work 提示符没变 正常现象,盘符各自记当前目录 用 cd /d D:\work,或先敲 D:
系统找不到指定的路径。 路径不存在、盘符写错,或 & 把命令拆断了 确认路径,加双引号
上面那条 + 'xxx' 不是内部或外部命令... 连着报两条 路径里有 &,被切成两条命令 路径整体加双引号
目录名无效 把文件当目录了 确认目标是目录
CMD 不支持将 UNC 路径作为当前目录。 cd 不支持网络路径 换 pushd
想退上级却停在根目录 已经在根了 用 cd \ 回根目录
popd 什么都没发生 栈是空的,它不报错 确认 pushd 确实执行过
盘符不存在(如本机没有 D:) 同样报「系统找不到指定的路径」 先确认盘符在不在

下一篇

走到目录之后,紧接着的真实需求是把东西从这里搬到那里。下一篇讲复制:copy、xcopy、robocopy 怎么选,为什么 copy 完子目录一个都没过去,xcopy /E 加了为什么还漏隐藏文件,robocopy /MIR 又为什么会把目标里多出来的东西删掉;pushd/popd 在搬运脚本里还会继续用。