计划任务的价值在于「人不在也能跑」,麻烦也在这里:出问题时没有窗口可看,只能靠任务登记的信息和日志反推。下面每条都本机实跑,测试目录 E:\cmd-demo\schtasks,所有任务名统一加 cmd-demo- 前缀,触发器只设未来时间或手动 /run,不真的等到点,测完全部删除。

建一条每日任务,先看它登记了什么

E:\cmd-demo\schtasks>schtasks /create /tn cmd-demo-daily /sc DAILY /st 23:59 /tr E:\cmd-demo\schtasks\task-info.bat /f
成功: 成功创建计划任务 "cmd-demo-daily"。

大多数任务的 /st 写成 23:59,保证验证期间不会被自动触发。/f 表示同名任务直接覆盖,不加时同名任务会先问是否替换。随后 /query /v /fo LIST 里有几个字段值得先看:

下次运行时间: 2026/11/20 23:59:00
登录状态:     只使用交互方式
要运行的任务: E:\cmd-demo\schtasks\task-info.bat
起始于:       N/A
作为用户运行: jsx13
上次结果:     267011
  • 267011 是「从未运行」的占位值,不是错误码。
  • 起始于: N/A 表示没有设置工作目录。
  • 作为用户运行 是创建者账号,不是脚本里的 %username%。
  • 登录状态: 只使用交互方式 说明这个任务只在当前用户登录时跑。

截图

四种触发器,差别在 /sc

/sc 决定什么时候触发,/st 只对 DAILY、ONCE 这类带时间的类型有意义:

schtasks /create /tn cmd-demo-onlogon /sc ONLOGON /tr ... /f
计划类型: 登陆时

schtasks /create /tn cmd-demo-onidle /sc ONIDLE /tr ... /f
错误: 必须指定 /I 值。

schtasks /create /tn cmd-demo-onidle /sc ONIDLE /i 10 /tr ... /f
计划类型: 在空闲时间

schtasks /create /tn cmd-demo-onstart /sc ONSTART /ru SYSTEM /tr ... /f
计划类型: 系统启动时

ONIDLE 必须带 /i 分钟数,少了直接失败。ONSTART 开机时还没有用户登录,通常配 /ru SYSTEM;ONLOGON 不需要 /st。这四种触发器只验证了登记结果,没有触发登录或重启,手动运行的验证在下面。

触发器只负责登记,验证时不用等到点:建完直接 /run 跑一次,再看 上次结果,能先排除路径和权限问题,剩下的才是触发器本身。

截图

/tr 带空格:创建成功不等于能跑

先看错误写法:

schtasks /create /tn cmd-demo-space-bad /sc ONCE /st 23:59 /tr "E:\cmd-demo\schtasks\dir with space\space task.bat" /f
成功: 成功创建计划任务 "cmd-demo-space-bad"。

schtasks /run /tn cmd-demo-space-bad
成功: 尝试运行 "cmd-demo-space-bad"。

schtasks /query /tn cmd-demo-space-bad /v /fo LIST
上次结果: -2147024894

创建和启动都返回成功,但任务实际没跑起来,-2147024894 就是 0x80070002,找不到文件。原因在登记的动作:要运行的任务 里存的是不带引号的路径,路径本身带空格,执行器没法把它当成一个文件。

正确写法要两层引号,内层交给任务计划程序保存:

schtasks /create /tn cmd-demo-space-ok /sc ONCE /st 23:59 /tr "\"E:\cmd-demo\schtasks\dir with space\space task.bat\"" /f
上次结果: 0
要运行的任务: "E:\cmd-demo\schtasks\dir with space\space task.bat"

/create 不校验路径是否存在,所以错误写法也能建成功。判断方法只有两个:看 要运行的任务 里有没有引号,或者手动 /run 看 上次结果。/st 用 24 小时制,写 25:00 会报「无效 starttime 值」,退出码同样是 -2147467259。

截图

任务里的当前目录,不是你的当前目录

任务脚本只做一件事:把当前目录、脚本目录、用户名写进日志。从 E:\cmd-demo\schtasks 创建并运行,日志是:

2026/11/20 周五 15:22:48.24 user=jsx13 cwd=C:\Windows\System32 dp0=E:\cmd-demo\schtasks\

cwd 是 C:\Windows\System32,和创建任务时所在的目录无关。schtasks /create 也没有设置起始目录的参数,起始于 因此是 N/A。脚本里写 log.txt,指的就是 C:\Windows\System32\log.txt,不是脚本旁边那个。

%~dp0 仍然指向脚本自己所在的目录,所以日志能正常写回 E:\cmd-demo\schtasks\。任务运行时没有窗口,脚本里的 echo 没人看,判断成败只能靠写进文件的日志和 上次结果。稳妥做法是在 bat 开头固定一行:

cd /d "%~dp0"

脚本里再调用别的 bat 或读写文件,也用 %~dp0 拼绝对路径,不要写相对路径。任务计划程序不会替你保留创建任务时所在的目录。

截图

当前账号与 SYSTEM 的区别

schtasks /query /tn cmd-demo-daily /v /fo LIST
登录状态: 只使用交互方式
作为用户运行: jsx13

schtasks /query /tn cmd-demo-onstart /v /fo LIST
登录状态: 交互方式/后台方式
作为用户运行: SYSTEM

当前账号的任务默认「只使用交互方式」,人没登录就不跑;SYSTEM 的任务是「交互方式/后台方式」,不需要登录会话就能执行。日志里的用户名也印证了这一点,SYSTEM 任务写出来的是机器账号:

2026/11/20 周五 15:22:58.37 user=JIANSX$ cwd=C:\Windows\System32 dp0=E:\cmd-demo\schtasks\

/rp 只在 /ru 指定了需要密码的账号时才用。给当前账号配错密码,创建直接失败,退出码 1:

错误: 用户名或密码不正确。

帮助里写「SYSTEM 账号会忽略 /rp」,但实测给 SYSTEM 配一个非空密码反而报同样的错;省略 /rp 或写成空值才能成功。账号没密码时,改任务还可能被追问运行账号密码,脚本里调用 schtasks /change 要留意这一点。

截图

/rl HIGHEST 在哪里看

/rl HIGHEST 在 /v 列表里看不到,要查 XML:

schtasks /create /tn cmd-demo-highest /sc ONCE /st 23:59 /tr ... /rl HIGHEST /f
<RunLevel>HighestAvailable</RunLevel>
<LogonType>InteractiveToken</LogonType>

不写 /rl 时,XML 里根本没有 RunLevel 节点,行为就是默认的受限权限。需要管理员权限的脚本才加,普通备份、清理任务没必要提权。

截图

change、run、delete

schtasks /change /tn cmd-demo-change /st 23:55
成功: 更改了计划任务 "cmd-demo-change" 的参数。
下次运行时间: 2026/11/20 23:55:00

schtasks /run /tn cmd-demo-change
成功: 尝试运行 "cmd-demo-change"。
上次结果: 0

schtasks /delete /tn cmd-demo-change /f
成功: 计划的任务 "cmd-demo-change" 被成功删除。

/change 只改指定参数,其余保持;改之前先 /query 记下原值,改完再查一次,才能确认只动了这一项。/run 立刻执行一次,不影响下次运行时间;/delete 加 /f 免确认。删完再查,退出码是 1:

错误: 系统找不到指定的文件。

/query、/run、/change、/delete 遇到不存在的任务都是这个结果,退出码 1。/delete 加 /f 免掉确认提示,适合脚本里清理。

截图

日志在哪看

日常先看 /query /v 的两个字段:

上次运行时间: 2026/11/20 15:22:48
上次结果:     0

上次结果 为 0 是成功,267011 是还没跑过,-2147024894 是找不到文件。更细的历史在事件查看器的 应用程序和服务日志 → Microsoft → Windows → TaskScheduler → Operational,但本机实测这个通道默认是关闭的:

enabled: false
logFileName: %SystemRoot%\System32\Winevt\Logs\Microsoft-Windows-TaskScheduler%4Operational.evtx

要启用得用管理员权限改通道设置,或直接在事件查看器里勾选「启用日志」。通道没开时,/query /v 就是唯一能看到的运行结果;启用之后才会记录任务启动、结束和失败的原因,比只看 0 或 1 更有用。

截图

测完把任务清干净

测试任务统一带前缀,清理时先列出来再逐条删除:

schtasks /query /fo LIST | findstr /i "cmd-demo-"
schtasks /delete /tn cmd-demo-daily /f

删除后要再查一遍,确认没有以 cmd-demo- 开头的记录,否则残留任务可能在下次登录或开机时真的跑起来。这一步和创建同样重要。

退出码

退出码 含义
0 创建、修改、删除、启动成功
1 任务不存在、同名任务未加 /f、用户名或密码错误
-2147467259 参数非法:/sc 不认识、/st 越界、ONIDLE 缺 /i

最后一种在 cmd 里显示成负数,会带来一个坑:

码=-2147467259
if-not-errorlevel-0-命中

if errorlevel 1 没有命中,因为它是「大于等于 1」,负数不满足。判断 schtasks 是否成功,用 if not "%errorlevel%"=="0",或者直接看 %errorlevel% 的值。

速查

写法 作用
/tn 名称 任务名,建议统一前缀便于清理
/tr 路径 要运行的程序或脚本
/sc DAILY 每天,配 /st
/sc ONLOGON 用户登录时
/sc ONSTART 系统启动时,常配 /ru SYSTEM
/sc ONIDLE 空闲时,必须配 /i 分钟
/st 23:59 开始时间,格式 24 小时
/ru SYSTEM 以 SYSTEM 运行,不需要密码
/rp 密码 配合 /ru,SYSTEM 别给非空值
/rl HIGHEST 最高权限,XML 里看 RunLevel
/query /tn X /v /fo LIST 查全部字段
/run /tn X 立刻跑一次
/change /tn X /st 23:55 改开始时间
/delete /tn X /f 删除,免确认

下一篇

定时任务能跑了,下一步是让脚本自己处理一批文件:按修改时间清理旧日志、按扩展名归档,forfiles /D、robocopy /MINAGE /MAXAGE 怎么选,批量处理时怎么避免重复和误删。